# Maintainer: restitux <restitux at ohea dot xyz>

_pkgbase=rtorrent_exporter
pkgname=prometheus-rtorrent-exporter
pkgver=1.2.1
pkgrel=1
pkgdsc='Expose prometheus metrics from a rtorrent instance.'
arch=('x86_64')
url="https://github.com/thde/${_pkgbase}"
license=('Apache-2.0')
makedepends=('go')
source=("${_pkgbase}-$pkgver.tar.gz::$url/archive/refs/tags/v$pkgver.tar.gz")
sha256sums=('6fcebabc804b9aba32e90b82b869135184f030b82fd7b73b62167a6075de4384')
backup=("etc/conf.d/$_pkgbase")

prepare(){
  mkdir -p "$srcdir/gopath"
  export GOPATH="$srcdir/gopath"
  cd "$srcdir/$_pkgbase-$pkgver"
  mkdir -p build/
}

build() {
  cd "$srcdir/$_pkgbase-$pkgver"
  local _goldflags="-w -s"
  go build \
    -trimpath -mod=readonly -modcacherw \
    -o "build/$_pkgbase" \
    -ldflags "$_goldflags" \
    .
}

package() {
  # install rtorrent_exporter
  install -Dm755 "$srcdir/$_pkgbase-$pkgver/build/$_pkgbase" "$pkgdir/usr/bin/$_pkgbase"

  # install conf.d
  install -Dm600 "$startdir/$_pkgbase.conf.d" "$pkgdir/etc/conf.d/$_pkgbase"

  # install systemd units
  install -Dm644 "$startdir/$_pkgbase.service" "$pkgdir/usr/lib/systemd/system/$_pkgbase.service"

  # install sys user
  install -Dm644 "$startdir/$_pkgbase.sysusers" "$pkgdir/usr/lib/sysusers.d/$_pkgbase.conf"

  # install license
  install -Dm644 "$srcdir/$_pkgbase-$pkgver/LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"

  # install README.md
  install -Dm644 "$srcdir/$_pkgbase-$pkgver/README.md" "$pkgdir/usr/share/doc/$pkgname/README.md"
}